第２講 再帰的呼び出しで魔方陣を作ろう！
第３話 プログラム本体（再帰的呼び出しプロシージャ）は？
再帰的呼び出しによる順列の作成のSub jyunretusakusei(g As Integer)
のｇに相当するのが、
| ０ | １ | ２ | ３ | |
| ０ | ０ | １ | ２ | ３ |
| １ | ４ | ５ | ６ | ７ |
| ２ | ８ | ９ | １０ | １１ |
| ３ | １２ | １３ | １４ | １５ |
の白の番号です。
魔方陣を再帰的に作り出すSubプロシージャを
Sub sakusei(g as integer)
と名付けると、
メインプロシージャから最初呼び出すときは、sakusei(0)
でなければなりません。
順列のときは、位置番号を１から始めましたが今回から０としているからです。
さて、問題は
Sub sakusei(g as integer)
・
・
・
End Sub
の中身をどうするかです。
数字の入れ方は順列のときと同じですが、
黄色の位置に来たときに、
行合計、列合計、対角線合計などが
同じ合計になっているか確認しなければなりません。
その合計値はｎ×（ｎ×ｎ＋１）÷２の計算で求められます。
というのは、ｎ次魔方陣の場合１からｎ×ｎまでの数字が入り、
そのすべての数字の合計は
１＋２＋３＋・・・＋ｎ×ｎ＝ｎ×ｎ×（ｎ×ｎ＋１）÷２
で、それを行数のｎで割ったものが各行などの合計値になるからです。
黄色はさらに
| ０ | １ | ２ | ３ | |
| ０ | ０ | １ | ２ | ３ |
| １ | ４ | ５ | ６ | ７ |
| ２ | ８ | ９ | １０ | １１ |
| ３ | １２ | １３ | １４ | １５ |
の４種類に分かれます。
３、７、８は行合計（横合計）
１２は列合計（縦合計）と対角線合計
１３、１４は列合計
１５は行合計、列合計、対角線合計
がそれぞれｎ×（ｎ×ｎ＋１）÷２
になっていることを確認しなければなりません。
以上より例えば、次のようなソース例が考えられます。
Sub sakusei(g As Integer)
Dim i As Integer, j As Integer, k As Integer
Dim l As Integer, hh As Integer, wa As Integer
j = g Mod n
i = Int(g / n)
For k = 1 To n * n
mah(i, j) = k
hh = 0
If tyouhukuhantei(k - 1) = 1 Then GoTo owari
tyouhukuhantei(k - 1) = 1
hh = 1
If j = n - 1 Then
wa = 0
For l = 0 To n - 1
wa = wa + mah(i, l)
Next
If wa <> Int(n * (n * n + 1) / 2) Then GoTo owari
End If
If i = n - 1 Then
wa = 0
For l = 0 To n - 1
wa = wa + mah(l, j)
Next
If wa <> Int(n * (n * n + 1) / 2) Then GoTo owari
End If
If i = n - 1 And j = 0 Then
wa = 0
For l = 0 To n - 1
wa = wa + mah(l, n - 1 - l)
Next
If wa <> Int(n * (n * n + 1) / 2) Then GoTo owari
End If
If i = n - 1 And j = n - 1 Then
wa = 0
For l = 0 To n - 1
wa = wa + mah(l, l)
Next
If wa <> Int(n * (n * n + 1) / 2) Then GoTo owari
End If
If g + 1 < n * n Then
sakusei (g + 1)
Else
cn = cn + 1
hyouji
End If
owari:
If hh = 1 Then tyouhukuhantei(k - 1) = 0
Next
mah(i, j) = 0
End Sub
GoTo owariはowari:に飛ぶ命令です。
かつてのＢＡＳＩＣの頃、GoTo文はスパゲティプログラムの元凶とされ、
今ではすっかり悪者扱いですが、
使い方によっては便利なものです。
飛ぶ場所を１箇所に決めておけば、
スパゲティにはなりません。
ですが、構造化プログラミングを意識し、
使用は最小限にすべきことは言うまでもありません。
以上のようにして魔方陣プログラム１ができあがります。
次講ではこのできがいいとは言えないプログラムの改善に取り組み、
１万倍以上の高速化に取り組みます。
その前に、プログラムについて疑問な点があると思いますので、
第４話でそれを解消していきましょう。
第２講第２話へ 第２項第４話へ 第３講第１話へ
